MoveHandler.qml

/*
 * Copyright (C) 2014-2016 Canonical Ltd.
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; version 3.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */
 
import QtQuick 2.12
import QtMir.Application 0.1 // For Mir singleton
import Lomiri.Components 1.3
import Utils 0.1
import "../Components"
 
QtObject {
    id: root
 
    property Item target // appDelegate
    property real buttonsWidth: 0
    property Item boundsItem
    property real boundsTopMargin: 0
 
    readonly property bool dragging: priv.dragging
    readonly property bool moving: priv.moving
 
    signal fakeMaximizeAnimationRequested(real amount)
    signal fakeMaximizeLeftAnimationRequested(real amount)
    signal fakeMaximizeRightAnimationRequested(real amount)
    signal fakeMaximizeTopLeftAnimationRequested(real amount)
    signal fakeMaximizeTopRightAnimationRequested(real amount)
    signal fakeMaximizeBottomLeftAnimationRequested(real amount)
    signal fakeMaximizeBottomRightAnimationRequested(real amount)
    signal stopFakeAnimation()
 
    property QtObject priv: QtObject {
        property real distanceX
        property real distanceY
        property bool dragging
        property bool moving
 
        readonly property int triggerArea: units.gu(8)
        property bool nearLeftEdge: target && target.maximizedLeft
        property bool nearTopEdge: target && target.maximized
        property bool nearRightEdge: target && target.maximizedRight
        property bool nearTopLeftCorner: target && target.maximizedTopLeft
        property bool nearTopRightCorner: target && target.maximizedTopRight
        property bool nearBottomLeftCorner: target && target.maximizedBottomLeft
        property bool nearBottomRightCorner: target && target.maximizedBottomRight
 
        property Timer mouseDownTimer: Timer {
            interval: 175
            onTriggered: Mir.cursorName = "grabbing"
        }
 
        function resetEdges() {
            nearLeftEdge = false;
            nearRightEdge = false;
            nearTopEdge = false;
            nearTopLeftCorner = false;
            nearTopRightCorner = false;
            nearBottomLeftCorner = false;
            nearBottomRightCorner = false;
        }
 
        // return the progress of mouse pointer movement from 0 to 1 within a corner square of the screen
        // 0 -> before the mouse enters the square
        // 1 -> mouse is in the outer corner
        // a is the corner, b is the mouse pos
        function progressInCorner(ax, ay, bx, by) {
            // distance of two points, a and b, in pixels
            var distance = Math.sqrt(Math.pow(bx-ax, 2) + Math.pow(by-ay, 2));
            // length of the triggerArea square diagonal