Servizio ScriptForge.String

Il servizio String fornisce una raccolta di metodi per l'eleborazione delle stringhe. Questi metodi possono essere usati per:

• Convalidare il contenuto delle stringhe

• Formattare le stringhe rimuovendo spazi, giustificandole o adattando i loro contenuti

• Usare le espressioni regolari per cercare e sostituire parti delle stringhe

• Applicare algoritmi di hash alle stringhe, ecc.

Definizioni

Interruzioni di riga

Il servizio String riconosce i seguenti tipi di interruzione di riga:

Spazi vuoti

Il servizio String riconosce i seguenti tipi di spazi:

Sequenze di escape

Il seguente è un elenco delle sequenze di escape che potete usare nelle stringhe.

Per fare in modo che la sequenza di escape "\n" sia interpretata alla lettera come una stringa, usate semplicemente "\\n" invece di "\" & Chr(10).

Caratteri non stampabili:

I caratteri che nel database dei caratteri Unicode sono definiti come “Altro” o “Separatore” sono considerati come caratteri non stampabili.

Anche i caratteri di controllo (codici ascii <= 0x1F) sono considerati come non stampabili.

Virgolette all'interno delle stringhe:

Per aggiungere delle virgolette all'interno delle stringhe usate \' (virgoletta) o \" (virgolette doppie). Per esempio:

• La stringa [str\'i\'nga] è interpretata come [str'i'nga]

• La stringa [str\"i\"nga] è interpretata come [str"i"nga]

Invocare il servizio

Prima di usare il servizio ScriptForge.String è necessario caricare la libreria ScriptForge usando:

      GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
  

Il caricamento della libreria creerà l'oggetto SF_String che può essere usato per chiamare i metodi del servizio String.

Il seguente frammento di codice mostra i tre modi per chiamare i metodi del servizio String (il metodo Capitalize viene usato come esempio):

    Dim s as String : s = "abc def"
    s = SF_String.Capitalize(s) ' Abc Def
  

    Dim s as String : s = "abc def"
    Dim svc : svc = SF_String
    s = svc.Capitalize(s) ' Abc Def
  

    Dim s as String : s = "abc def"
    Dim svc : svc = CreateScriptService("String")
    s = svc.Capitalize(s) ' Abc Def
  

Il frammento di codice seguente illustra come invocare i metodi del servizio String dagli script in Python. Il metodo IsIPv4 è usato come esempio.

    from scriptforge import CreateScriptService
    svc = CreateScriptService("String")
    ip_address = '192.168.0.14'
    svc.IsIPv4(ip_address) # True
  

Proprietà

L'oggetto SF_String fornisce le seguenti proprietà per gli script in Basic:

Potete usare le proprietà precedenti per identificare o inserire i corrispondenti caratteri all'interno delle stringhe. Per esempio, il carattere di A capo può essere sostituito da SF_String.sfLF.

Il primo argomento della maggior parte dei metodi è la stringa da prendere in considerazione. Questa viene sempre passata per riferimento e lasciata inalterata. Metodi come Capitalize, Escape, ecc., restituiscono una nuova stringa al termine dell'esecuzione.

Considerato che Python incorpora il supporto completo per le stringhe, la maggior parte dei metodi del servizio String è disponibile solamente per gli script in Basic. I metodi disponibili per Basic e Python sono: HashStr, IsADate, IsEmail, IsFileName, IsIBAN, IsIPv4, IsLike, IsSheetName, IsUrl, SplitNotQuoted e Wrap.

Capitalize

Rende maiuscolo il primo carattere di ogni parola della stringa di partenza.

svc.Capitalize(inputstr: str): str

inputstr: la stringa di cui rendere maiuscola l'iniziale.

    Dim sName as String : sName = "john smith"
    Dim sCapitalizedName as String
    sCapitalizedName = SF_String.Capitalize(sName)
    MsgBox sCapitalizedName 'John Smith
  

Count

Conta il numero di occorrenze di una sottostringa o di un'espressione regolare all'interno di una stringa.

svc.Count(inputstr: str, substring: str, [isregex: bool], [casesensitive: bool]): int

inputstr: la stringa inserita da esaminare

substring: la sottostringa o l'espressione regolare da usare durante la ricerca

isregex: usate True se la sottostringa è un'espressione regolare (predefinito = False)

casesensitive: la ricerca può distinguere o no tra minuscole e maiuscole (predefinito = False).

    'Conta le occorrenze della sottostringa "or" all'interno della stringa di partenza (restituisce 2)
    MsgBox SF_String.Count("Lorem ipsum dolor sit amet, consectetur adipiscing elit.", "or", CaseSensitive := False)
    'Conta il numero di parole con solo lettere minuscole (restituisce 7)
    MsgBox SF_String.Count("Lorem ipsum dolor sit amet, consectetur adipiscing elit.", "\b[a-z]+\b", IsRegex := True, CaseSensitive := True)
  

Per saperne di più sulle espressioni regolari, fate riferimento alla documentazione di Python sulle Operazioni con le Espressioni regolari.

EndsWith

Restituisce True se una stringa termina con la sottostringa indicata.

La funzione restituisce False se la stringa o la sottostringa hanno una lunghezza pari a = 0, o se la sottostringa è più lunga della stringa.

svc.EndsWith(inputstr: str, substring: str, [casesensitive: bool]): bool

inputstr: la stringa da controllare.

substring: la sottostringa da cercare alla fine di inputstr.

casesensitive: la ricerca può distinguere o no tra minuscole e maiuscole (predefinito = False).

    'Restituisce True perchè il metodo è stato chiamato con il valore predefinito di CaseSensitive = False
    MsgBox SF_String.EndsWith("abcdefg", "EFG")
    'Restituisce False a causa del parametro CaseSensitive
    MsgBox SF_String.EndsWith("abcdefg", "EFG", CaseSensitive := True)
  

Escape

Converte le interruzioni di riga e le tabulazioni contenute nella stringa di partenza nella loro equivalente sequenza di escape (\\, \n, \r, \t).

svc.Escape(inputstr: str): str

inputstr: la stringa da convertire.

    'Restituisce la stringa "abc\n\tdef\\n"
    MsgBox SF_String.Escape("abc" & Chr(10) & Chr(9) & "def\n")
  

ExpandTabs

Sostituisce i caratteri di tabulazione Chr(9) con caratteri di spazio in modo da replicare il comportamento degli stop del tabulatore.

Se trova un'interruzione di riga, va a capo e il contatore dei caratteri viene azzerato.

svc.ExpandTabs(inputstr: str, [tabsize: int]): str

inputstr: la stringa da espandere

tabsize: questo parametro viene usato per determinare gli stop del tabulatore usando la formula: TabSize + 1, 2 * TabSize + 1 , ... N * TabSize + 1 (predefinito = 8)

    Dim myText as String
    myText = "100" & SF_String.sfTAB & "200" & SF_String.sfTAB & "300" & SF_String.sfNEWLINE & _
             "X"  & SF_String.sfTAB & "Y" & SF_String.sfTAB & "Z"
    MsgBox SF_String.ExpandTabs(myText)
    '100     200     300
    'X       Y       Z
  

FilterNotPrintable

Sostituisce tutti i caratteri non stampabili della stringa inserita con il carattere indicato.

svc.FilterNotPrintable(inputstr: str, [replacedby: str]): str

inputstr: la stringa in cui cercare

replacedby: zero, uno o più caratteri che sostituiranno tutti i caratteri non stampabili in inputstr (predefinito = "")

    Dim LF : LF = Chr(10)
    Dim myText as String
    myText = "àén ΣlPµ" & LF & " Русский" & "\n"
    MsgBox SF_String.FilterNotPrintable(myText)
    ' "àén ΣlPµ Русский\n"
  

FindRegex

Trova, all'interno di una stringa, una sottostringa conforme all'espressione regolare precisata.

svc.FindRegex(inputstr: str, regex: str, [start: int], [casesensitive: bool], [forward: bool]): str

inputstr: la stringa in cui cercare

regex: l'espressione regolare

start: la posizione, all'interno della stringa, dalla quale inizierà la ricerca. Questo parametro viene passato come riferimento, perciò dopo l'esecuzione il valore di start punterà al primo carattere della sottostringa trovata. Se non viene trovata alcuna sottostringa corrispondente, start verrà impostato a 0.

casesensitive: la ricerca può distinguere o meno tra minuscole e maiuscole (predefinito = False).

forward: determina la direzione della ricerca. Se True, la ricerca avviene in avanti. Se False la ricerca avviene all'indietro (predefinito = True)

Alla prima iterazione, se forward = True, start deve essere uguale a 1, mentre se forward = False, start deve essere uguale a Len(inputstr)

    Dim lStart As Long : lStart = 1
    Dim result as String
    result = SF_String.FindRegex("abCcdefghHij", "C.*H", lStart, CaseSensitive := True)
    MsgBox lStart & ": " & result
    '3: CcdefghH
  

Nell'esempio sopra, il nuovo valore di lStart può essere usato per continuare a cercare la stessa stringa inserita, impostando il parametro Start a lStart + Len(result) all'iterazione successiva.

HashStr

Le funzioni di hash sono usate in alcuni algoritmi crittografici, nelle firme digitali, nei codici di autenticazione dei messaggi, nel rilevamenti di manipolazioni, nelle "impronte digitali", nei checksum (controllo di integrità dei messaggi), nelle tabelle di hash, nella memorizzazione delle password e per molto altro ancora.

Il metodo HashStr restituisce il risultato di una funzione di hash, applicata alla stringa specificata, usando un algoritmo specifico, in formato stringa esadecimale con lettere minuscole.

Gli algoritmi di hash supportati sono: MD5, SHA1, SHA224, SHA256, SHA384 e SHA512.

svc.HashStr(inputstr: str, algorithm: str): str

inputstr: la stringa di cui calcolare l'hash. Si presume che sia codificata in UTF-8. L'algoritmo di hash considererà la stringa come un flusso di byte.

algorithm: uno degli algoritmi supportati ed elencati in precedenza, passato in formato stringa.

    MsgBox SF_String.HashStr("œ∑¡™£¢∞§¶•ªº–≠œ∑´®†¥¨ˆøπ‘åß∂ƒ©˙∆˚¬", "MD5")
    ' c740ccc2e201df4b2e2b4aa086f35d8a
  

    svc = CreateScriptService("String")
    bas = CreateScriptService("Basic")
    a_string = "œ∑¡™£¢∞§¶•ªº–≠œ∑´®†¥¨ˆøπ‘åß∂ƒ©˙∆˚¬"
    hash_value = svc.HashStr(a_string, "MD5")
    bas.MsgBox(hash_value)
    # c740ccc2e201df4b2e2b4aa086f35d8a
  

HtmlEncode

Codifica la stringa inserita nei codici carattere HTML, sostituendo i caratteri speciali con il loro corrispondente &.

Per esempio, il carattere é sarà sostituito con &eacute; o con un codice numerico HTML equivalente.

svc.HtmlEncode(inputstr: str): str

inputstr: la stringa da codificare

    MsgBox SF_String.HtmlEncode("<a href=""https://a.b.com"">From α to ω</a>")
    ' "&lt;a href=&quot;https://a.b.com&quot;&gt;From &#945; to &#969;&lt;/a&gt;"
  

IsADate

Restituisce True se la stringa inserita è una data valida secondo il formato data specificato.

svc.IsADate(inputstr: str, [dateformat: str]): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False

dateformat: il formato data, come stringa. Può essere uno tra "AAAA-MM-GG" (predefinito), "GG-MM-AAAA" o "MM-GG-AAAA"

Il trattino (-) può essere sostituito con un punto (.), una barra (/) o uno spazio.

Se il formato non è valido, il metodo restituisce False.

    MsgBox SF_String.IsADate("2020-12-31", "YYYY-MM-DD") ' True
  

Questo metodo controlla il formato della stringa inserita senza eseguire alcun controllo specifico in base al calendario. Perciò non controlla se la stringa inserita rispetta gli anni bisestili o i mesi da 30 o 31 giorni. Per questo consultate la funzione incorporata IsDate.

L'esempio sottostante mostra la differenza tra i metodi IsADate (ScriptForge) e la funzione (incorporata) IsDate.

    Dim myDate as String : myDate = "2020-02-30"
    MsgBox SF_String.IsADate(myDate, "YYYY-MM-DD") 'True
    MsgBox IsDate(myDate) ' False
  

    svc = CreateScriptService("String")
    s_date = "2020-12-31"
    result = svc.IsADate(s_date) # True
  

IsAlpha

Restituisce True se tutti i caratteri della stringa sono alfabetici.

I caratteri alfabetici sono quei caratteri che nella documentazione Unicode Character Database sono definiti come Letter.

svc.IsAlpha(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsAlpha("àénΣlPµ") ' True
    MsgBox SF_String.IsAlpha("myVar3") ' False
  

IsAlphaNum

Restituisce True se tutti i caratteri della stringa sono alfabetici, numerici o "_" (trattino basso). Il primo carattere non deve essere una cifra.

svc.IsAlphaNum(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsAlphaNum("_ABC_123456_abcàénΣlPµ") ' True
    MsgBox SF_String.IsAlphaNum("123ABC") ' False
  

IsAscii

Restituisce True se tutti i caratteri della stringa sono caratteri ASCII.

svc.IsAscii(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsAscii("a%?,25") ' True
    MsgBox SF_String.IsAscii("abcàénΣlPµ") ' False
  

IsDigit

Restituisce True se tutti i caratteri della stringa sono cifre.

svc.IsDigit(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsDigit("123456") ' True
    MsgBox SF_String.IsDigit("_12a") ' False
  

IsEmail

Restituisce True se la stringa è un indirizzo di posta elettronica valido.

svc.IsEmail(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsEmail("first.last@something.org") ' True
    MsgBox SF_String.IsEmail("first.last@something.com.br") ' True
    MsgBox SF_String.IsEmail("first.last@something.123") ' False
  

    svc = CreateScriptService("String")
    bas = CreateScriptService("Basic")
    bas.MsgBox(svc.IsEmail("first.last@something.org")) # True
    bas.MsgBox(svc.IsEmail("first.last@something.com.br")) # True
    bas.MsgBox(svc.IsEmail("first.last@something.123")) # False
  

IsFileName

Restituisce True se la stringa è un nome di file valido per il sistema operativo specificato.

svc.IsFileName(inputstr: str, [osname: str]): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

osname: il nome del sistema operativo, in formato stringa. Può essere "WINDOWS", "LINUX", "MACOSX" o "SOLARIS".

Il valore predefinito è il sistema operativo corrente nel quale lo script viene eseguito.

    MsgBox SF_String.IsFileName("/home/user/Documents/a file name.odt", "LINUX") ' True
    MsgBox SF_String.IsFileName("C:\home\a file name.odt", "LINUX") ' False
    MsgBox SF_String.IsFileName("C:\home\a file name.odt", "WINDOWS") ' True
  

    svc = CreateScriptService("String")
    bas = CreateScriptService("Basic")
    bas.MsgBox(svc.IsFileName("/home/user/Documents/a file name.odt", "LINUX")) # True
    bas.MsgBox(svc.IsFileName(r"C:\home\a file name.odt", "LINUX")) # False
    bas.MsgBox(svc.IsFileName(r"C:\home\a file name.odt", "WINDOWS")) # True
  

IsHexDigit

Restituisce True se tutti i caratteri della stringa sono cifre esadecimali.

svc.IsHexDigit(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

Le cifre esadecimali possono avere il prefisso "0x" o "&H".

    MsgBox SF_String.IsHexDigit("&H00FF") ' True
    MsgBox SF_String.IsHexDigit("08AAFF10") ' True
    MsgBox SF_String.IsHexDigit("0x18LA22") ' False
  

IsIBAN

Restituisce True se la stringa è un IBAN (International Bank Account Number) valido. Il confronto non distingue tra minuscole e maiuscole.

svc.IsIBAN(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

True se la stringa contiene un codice IBAN valido.

    ' Basic
    MsgBox SF_String.IsIBAN("BR15 0000 0000 0000 1093 2840 814 P2") ' True
  

    # Python
    result = svc.IsIBAN("BR15 0000 0000 0000 1093 2840 814 P2") # True
  

IsIPv4

Restituisce True se la stringa è un indirizzo IP(v4) valido.

svc.IsIPv4(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsIPv4("192.168.1.50") ' True
    MsgBox SF_String.IsIPv4("192.168.50") ' False
    MsgBox SF_String.IsIPv4("255.255.255.256") ' False
  

    svc = CreateScriptService("String")
    bas = CreateScriptService("Basic")
    bas.MsgBox(svc.IsIPv4("192.168.1.50")) # True
    bas.MsgBox(svc.IsIPv4("192.168.50")) # False
    bas.MsgBox(svc.IsIPv4("255.255.255.256")) # False
  

IsLike

Restituisce True se l'intera stringa inserita corrisponde a un determinato schema contenente caratteri jolly.

svc.IsLike(inputstr: str, pattern: str, [casesensitive: bool]): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

pattern: lo schema in formato stringa. I caratteri jolly sono:

• "?" rappresenta un singolo carattere qualsiasi;

• "*" rappresenta zero, uno o più caratteri.

casesensitive: la ricerca può distinguere o meno tra minuscole e maiuscole (predefinito = False).

    MsgBox SF_String.IsLike("aAbB", "?A*") ' True
    MsgBox SF_String.IsLike("C:\a\b\c\f.odb", "?:*.*") ' True
    MsgBox SF_String.IsLike("name:host", "?*@?*") ' False
    MsgBox SF_String.IsLike("@host", "?*@?*") ' False
  

    svc = CreateScriptService("String")
    bas = CreateScriptService("Basic")
    bas.MsgBox(svc.IsLike("aAbB", "?A*")) # True
    bas.MsgBox(svc.IsLike(r"C:\a\b\c\f.odb", "?:*.*")) # True
    bas.MsgBox(svc.IsLike("name:host", "?*@?*")) # False
    bas.MsgBox(svc.IsLike("@host", "?*@?*")) # False
  

IsLower

Restituisce True se tutti i caratteri della stringa sono lettere minuscole. I caratteri non alfabetici vengono ignorati.

svc.IsLower(inputstr: str): bool

InputStr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsLower("abc'(-xy4z") ' True
    MsgBox SF_String.IsLower("1234") ' True
    MsgBox SF_String.IsLower("abcDefg") ' False
  

IsPrintable

Restituisce True se tutti i caratteri della stringa sono stampabili.

svc.IsPrintable(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsPrintable("àén ΣlPµ Русский") ' True
    MsgBox SF_String.IsPrintable("First line." & Chr(10) & "Second Line.") ' False
  

IsRegex

Restituisce True se l'intera stringa inserita corrisponde all'espressione regolare specificata.

svc.IsRegex(inputstr: str, regex: str, [casesensitive: bool]): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

regex: l'espressione regolare. Se vuota, il metodo restituisce False.

casesensitive: la ricerca può distinguere o meno tra minuscole e maiuscole (predefinito = False).

        MsgBox SF_String.IsRegex("aAbB", "[A-Za-z]+") ' True
        MsgBox SF_String.IsRegex("John;100", "[A-Za-z]+;[0-9]+") ' True
        MsgBox SF_String.IsRegex("John;100;150", "[A-Za-z]+;[0-9]+") ' False
      

IsSheetName

Restituisce True se la stringa inserita è un nome valido di un foglio di Calc.

svc.IsSheetName(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsSheetName("1àbc + ""déf""") ' True
    MsgBox SF_String.IsSheetName("[MySheet]") ' False
  

    svc = CreateScriptService("String")
    bas = CreateScriptService("Basic")
    bas.MsgBox(svc.IsSheetName("1àbc + ""déf""")) # True
    bas.MsgBox(svc.IsSheetName("[MySheet]")) # False
  

Il nome di un foglio non deve contenere i caratteri [ ] * ? : / \ o il carattere ' (apostrofo) come primo o ultimo carattere.

IsTitle

Restituisce True se il primo carattere di ogni parola è maiuscolo e i restanti caratteri sono minuscoli.

svc.IsTitle(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsTitle("This Is The Title Of My Book") ' True
    MsgBox SF_String.IsTitle("This is the Title of my Book") ' False
    MsgBox SF_String.IsTitle("Result Number 100") ' True
  

IsUpper

Restituisce True se tutti i caratteri della stringa sono maiuscoli. I caratteri non alfabetici vengono ignorati.

svc.IsUpper(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsUpper("ABC'(-XYZ") ' True
    MsgBox SF_String.IsUpper("A Title") ' False
  

IsUrl

Restituisce True se la stringa è un indirizzo URL (Uniform Resource Locator) assoluto valido. Sono supportati solo i protocolli http, https e ftp.

svc.IsUrl(inputstr: str): bool

inputstr: la stringa da controllare. Se vuota, il metodo restituisce False.

    MsgBox SF_String.IsUrl("http://foo.bar/?q=Test%20URL-encoded%20stuff") ' True
    MsgBox SF_String.IsUrl("www.somesite.org") ' False
  

    svc = CreateScriptService("String")
    bas = CreateScriptService("Basic")
    bas.MsgBox(svc.IsUrl("http://foo.bar/?q=Test%20URL-encoded%20stuff")) # True
    bas.MsgBox(svc.IsUrl("www.somesite.org")) # False
  

IsWhitespace

Restituisce True se tutti i caratteri della stringa sono spazi bianchi