# -*- text -*-
# --------------------------------------------------------------------
unix:include( ../config.pro )
win32:DEFINES   += WIN32
# --------------------------------------------------------------------
TEMPLATE	= app
CONFIG		+= qt windows
win32:RC_FILE  	= ipe.rc
# --------------------------------------------------------------------
DEFINES         += QT_NO_ASCII_CAST
kde:DEFINES	+= IPE_KDE
# --------------------------------------------------------------------
# Headers that moc needs to see:
HEADERS		+= appui.h
HEADERS		+= dialogs.h
HEADERS		+= styles.h
HEADERS		+= props.h
# --------------------------------------------------------------------
SOURCES		+= appui.cpp
SOURCES		+= initui.cpp
SOURCES		+= loadsave.cpp
SOURCES		+= main.cpp
SOURCES         += dialogs.cpp
SOURCES         += images.cpp
SOURCES         += master.cpp
SOURCES		+= props.cpp
SOURCES		+= styles.cpp		   
SOURCES		+= topng.cpp
# --------------------------------------------------------------------
TARGET		= ipe
# --------------------------------------------------------------------
INTERFACES	+= dlgpref.ui
INTERFACES	+= dlgdirprefs.ui
INTERFACES	+= dlgpagepres.ui
INTERFACES	+= dlgdocprop.ui
INTERFACES	+= dlglatexerr.ui
INTERFACES	+= dlgstyles.ui
INCLUDEPATH	+= ../include
INCLUDEPATH	+= ../ipemodel
INCLUDEPATH	+= ../ipecanvas
kde:INCLUDEPATH	+= $${KDE_INCLUDE}
DEPENDPATH      += ../include
DEPENDPATH      += ../ipemodel
DEPENDPATH      += ../ipecanvas
# --------------------------------------------------------------------
OBJECTS_DIR	= ../../build/obj/ipe
DESTDIR		= ../../build/bin
win32:LIBS	+= ../../build/lib/ipemodel.lib
win32:LIBS	+= ../../build/lib/ipecanvas.lib
win32:LIBS      += ../../build/lib/libipe.lib
win32:LIBS      += ../../../freetype/lib/freetype.lib
unix:LIBS       += -L../../build/lib -lipemodel -lipecanvas -lipe
unix:LIBS	+= $${QMAKE_LIBS_DYNLOAD}
kde:LIBS	+= -lkdecore
win32:TARGETDEPS += ../../build/lib/ipemodel.lib
win32:TARGETDEPS += ../../build/lib/ipecanvas.lib
win32:TARGETDEPS += ../../build/bin/libipe.dll
# --------------------------------------------------------------------
unix:documentation.path = $${IPEDOCDIR}
unix:documentation.files = ../../doc/*
unix:headers.path = $${IPEHEADERDIR}
unix:headers.files = ../include/*
unix:manpages.path = $${IPEMANDIR}
unix:manpages.files = ../../man/*
unix:target.path = $${IPEBINDIR}
unix:INSTALLS   += headers target documentation manpages
# --------------------------------------------------------------------
